#!/bin/csh -f
#------------------------------------
#$ -l h_cpu=0:20:00
#$ -pe ac.alloc 1
#$ -r n
#------------------------------------
#
# Usage: nc_to_vis5d ncfile
#
# atw 16oct2003

set name = `basename $0`

if ($#argv < 1) then
   cat <<EOF
Usage: $name ncfile
Converts a NetCDF file to Vis5d format.
The output file will have the same name as the input file but with the
extension replaced by ".v5d".  The conversion is subject to the
limitations of the Ferret writev5d function: all variables must have
the same XYT axes, and there cannot be non-matching overlapping
z-coordinates between different variables.
EOF
   exit 1
else
   set in_file = $1
   if (! -f $in_file) then
      echo "$in_file is not a valid input file."
      goto err
   endif
endif
set out_root = $in_file:r

setenv PATH ${PATH}:/usr/local/vis5d+/bin

# name of temporary file
set tmp = $out_root.$name.$$.tmp

# get the list of all variables
set varlist = (`ncdump -h $in_file | sed -n '/^variables:/,/^\/\/ global attributes:/p' | grep -v '[:={}]' | sed 's/[(),]/ /g' | awk 'NF>2 && $2!~$3 {print $2}'`) || goto err

if ($#varlist > 8) then
   echo "ERROR: more than 8 variables in input file $in_file"
   goto err
endif

# use Ferret to dump all variables to a Vis5d file
#ferret -noverify -nojnl -gif << EOF >& /dev/null || goto err
ferret -memsize 200 -nojnl -gif << EOF || goto err
use "$in_file"; go vis5d_write "$tmp" $varlist; quit
EOF

# create or overwrite the output file
mv -f $tmp $out_root.v5d || goto err

exit 0

err:
   echo "$name aborted on error."
   exit 1

#======================================================================
#  U.S. Department of Commerce (DOC) Software License for script 
#  developed at the Geophysical Fluid Dynamics Laboratory/NOAA.
#
#  1. Scope of License
#
#   Subject to all the terms and conditions of this license, DOC grants
#   USER the royalty-free, nonexclusive, nontransferable, and worldwide
#   rights to reproduce, modify, and distribute this script
#   developed at the Geophysical Fluid Dynamics Laboratory/NOAA, herein
#   referred to as the Product.
#
#  2. Conditions and Limitations of Use
#
#   Warranties.  Neither the U.S. Government, nor any agency or
#     employee thereof, makes any warranties, expressed or implied,
#     with respect to the Product provided under this License,
#     including but not limited to the implied warranties or
#     merchantability and fitness for any particular purpose.
#
#   Liability.  In no event shall the U.S. Government, nor any agency
#     or employee thereof, be liable for any  direct, indirect, or
#     consequential damages flowing from the use of the Product
#     provided under this License.
#
#   Non-Assignment.  Neither this License nor any rights granted
#     hereunder are transferable or assignable without the explicit
#     prior written consent of DOC. 
#
#   Names and Logos.  USER shall not substitute its name or logo for the
#     name or logo of DOC, or any of its agencies, in identification of
#     the Product.
#
#   Export of technology.  USER shall comply with all U.S. laws and
#     regulations restricting the export of the Product to other
#     countries.  
#
#   Governing Law.  This License shall be governed by the laws of 
#     United States as interpreted and applied by the Federal courts 
#     in the District of Columbia.
#
#  3. Term of License This License shall remain in effect as long as USER
#     uses the Product in accordance with Paragraphs 1 and 2.
#======================================================================